盛大新春版之盛大酒馆功能脚本js
;关于脚本命令(设置请酒显示内容) PLAYDRINKMSG 消息位置(1[上面],2[下面]) 消息内容(跟#say一样)
;该命令有个要注意的地方
;例如
;PLAYDRINKMSG 1 你身边并没有可寄丰了的英雄。\<重新寄放英雄/@SaveHero>
;PLAYDRINKMSG 2 嘿嘿……我可不会比你先醉倒，保管陪\你喝爽了！
;如果按照上面的方式，链接<重新寄放英雄>点击后会出现无效的情况，必需放到后面才会有效
;例如
;PLAYDRINKMSG 2 嘿嘿……我可不会比你先醉倒，保管陪\你喝爽了！
;PLAYDRINKMSG 1 你身边并没有可寄丰了的英雄。\<重新寄放英雄/@SaveHero>
;也就是说，只对最后一次使用PLAYDRINKMSG命令中的链接有效
;新增命令列表,在下面脚本中都有使用
;脚本命令(设置比酒显示内容) PLAYDRINKMSG 消息位置(1[上面],2[下面]) 消息内容(跟#say一样)
;脚本命令(打开请酒界面) OPENPLAYDRINK 人物头像(0,1,2) 人物名称(0:翔天,1:辰星,2:影月)
;脚本命令(打开比酒界面) OPENPLAYDRINK 人物头像(0,1,2) 人物名称(0:翔天,1:辰星,2:影月) DRINK
;关闭对话框(包括请酒和比酒) CLOSEDRINK
;创建英雄，CREATEHERO 2 1 TRUE 使用方法跟原来的一样，只是后面加个参数TRUE，代表为创建第二个英雄
;寄存英雄 SAVEHERO
;取回英雄 GetHero
(@@BuHero @PlayDrink)
[@main]
<请酒$寄放英雄/@Drink>\
<取回英雄/@GetHero>\
<创建英雄\">1/@@buHero>\
<比酒/@PlayDrink>\
;------------------------------比酒段开始-------------------------------------------------------------------
[@PlayDrink]
请把酒放上去
;成功提交烧酒触发该段
[~PlayDrink_Game]
#if
#act
PLAYDRINKMSG 1 <$USERNAME>，酒之道也可以算作我修行的一部\分，让我看看你的表现吧。
PLAYDRINKMSG 2 嘿嘿……我可不会比你先醉倒，保管陪\你喝爽了！
;脚本命令(设置比酒显示内容) PLAYDRINKMSG 消息位置(1[上面],2[下面]) 消息内容(跟#say一样)
OPENPLAYDRINK 1 辰星 DRINK
;脚本命令(打开比酒界面) OPENPLAYDRINK 人物头像(0,1,2) 人物名称(0:翔天,1:辰星,2:影月) DRINK
;玩家喝醉了
[~PlayDrink_Self_Drunk]
#if
#act
PLAYDRINKMSG 1 没看盛大,不知道盛大讲了什么！
PLAYDRINKMSG 2 盛大太绝,想输想醉都难.....!
;NPC喝醉了
[~PlayDrink_Npc_Drunk]
#if
#act
PLAYDRINKMSG 1 呃,看来令天我是有点喝多了……！
PLAYDRINKMSG 2 啊……前辈,您别醉呀……\ \<我下次再来/@CloseDrink>
[@CloseDrink]
#if
#act
CLOSEDRINK
;关闭对话框
;NPC输了
[~PlayDrink_Npc_Loss]
#if
#act
PLAYDRINKMSG 1 好久没有这种感觉了,酒意可谓"点到\即止",看来你也深明其理啦.！
PLAYDRINKMSG 2 呵呵,这次陪前辈喝酒,前辈已经喝得\尽兴,不知可否帮我个忙?\<招幕英雄/@CrHero>!
[@CrHero]
<创建英雄\">1/@@buHero>\
;玩家输了
[~PlayDrink_Self_Loss]
#if
#act
PLAYDRINKMSG 1 没看盛大,不知道盛大讲了什么！
PLAYDRINKMSG 2 盛大太绝,想输想醉都难.....!
;玩家让NPC喝酒
[~PlayDrink_SelfToNpc]
#if
#act
PLAYDRINKMSG 1 好！
PLAYDRINKMSG 2 就这坛了！请前辈来喝!
;玩家让玩家喝酒
[~PlayDrink_SelfToSelf]
#if
#act
PLAYDRINKMSG 1 ……
PLAYDRINKMSG 2 就这坛了！我自己喝！
;NPC让玩家喝酒
[~PlayDrink_NpcToSelf]
#if
#act
PLAYDRINKMSG 1 就这坛了！你来喝吧！
PLAYDRINKMSG 2 谢谢前辈！
;NPC让NPC喝酒
[~PlayDrink_NpcToNpc]
#if
#act
PLAYDRINKMSG 1 就这坛了！我来喝！
PLAYDRINKMSG 2 前辈尽管喝！
;划拳平局
[~PlayDrink_Dogfall]
#if
#act
PLAYDRINKMSG 1 那再来一局吧。
PLAYDRINKMSG 2 来就来！
;划拳NPC赢
[~PlayDrink_NpcWil]
#if
#act
PLAYDRINKMSG 1 嗯，不错，那我选了。
PLAYDRINKMSG 2 真倒霉，我就不信赢不了你。
;划拳玩家赢
[~PlayDrink_PlayWil]
#if
#act
PLAYDRINKMSG 1 <$USERNAME>，你选吧。
PLAYDRINKMSG 2 哈哈哈，还是我厉害吧~\选哪一坛好呢？
;------------------------------比酒段结束-------------------------------------------------------------------
;------------------------------招第二个英雄开始,其实跟以前的差不多,就是创建英雄命令多加个参数-------------
[@@buHero]
#if
#act
CREATEHERO 2 1 TRUE
;创建英雄，使用方法跟原来的一样，只是后面加个参数TRUE，代表为创建第二个英雄
[@CreateingHero]
系统正在接受申请，请稍候……\
<关闭/@exit>
[@HaveHero]
您已经有英雄了。\
<关闭/@exit>
[@SetHeroName]
请先给您的英雄取名字。\
<关闭/@exit>
;------------------------------招英雄结束-------------------------------------------------------------------
;------------------------------请酒/寄存英雄开始-------------------------------------------------------------------
[@Drink]
#if
#act
PLAYDRINKMSG 1 酒意需要品味，生命的动人之处常会在不经意\之间显现。我们在小酌中慢慢体会\吧。
PLAYDRINKMSG 2 小提示：请将包裹栏中的酒放至酒碟上。
;脚本命令(设置请酒显示内容) PLAYDRINKMSG 消息位置(1[上面],2[下面]) 消息内容(跟#say一样)
OPENPLAYDRINK 1 辰星
;脚本命令(打开请酒界面) OPENPLAYDRINK 人物头像(0,1,2) 人物名称(0:翔天,1:辰星,2:影月)
;请酒成功后触发该段
[~PlayDrink_Ok]
#if
#act
PLAYDRINKMSG 1 天道自然，在自然之中追寻平衡本百易事，但\这酒令我有了一些顿悟。\<寄放英雄/@SaveHero>
[@SaveHero]
#if
#act
SAVEHERO
;寄存英雄
//寄存英雄成功
[~PlayDrink_HeroOk]
#if
#act
CLOSEDRINK
;关闭请酒对话框
[~PlayDrink_NotHero]
#if
#act
CLOSEDRINK
MessageBox 你没有可寄存的英雄
[~PlayDrink_HeroBegin]
#if
#act
PLAYDRINKMSG 1 你身边并没有可寄丰了的英雄。\<重新寄放英雄/@SaveHero>
;------------------------------请酒/寄存英雄结束-------------------------------------------------------------------
;------------------------------取回英雄开始-------------------------------------------------------------------
[@GetHero]
#if
#act
GetHero
;取回英雄
;在QFunction.txt下增加如下脚本
[@GetHeroBak]
取回英雄失败，你已带了一位英雄了
[@GetHeroOk]
取回英雄成功
;------------------------------取回英雄结束---------------------------------------------------
| 